Tutorial sobre ASP - Francisco José Calvo Fernández

A continuación se expondrán unos ejemplos de los usos más comunes de ASP (aparte de las conexiones a las bases de datos, claro), con su código fuente.

Al concluir este capítulo usted sabrá manejarse con toda soltura con ASP y será capaz de resolver cualquier problemas que se le presente en ASP.

Envío de datos desde un formulario a una dirección de correo

Muchas veces necesitamos en nuestro sitio web, un formulario que capture datos de nuestros visitantes y deseamos recibir esos datos en nuestra casilla de correo. Para ello utilizaremos un componente denominado CDONT y es parte del servicio SMTP de Internet Information Server 4.

Este componente nos permite mediante unas pocas líneas de ASP, enviar y recibir mail. Manos a la obra:

Necesitamos una página con el formulario, a la cual llamaremos form.html:

<html>
<head>
</head>
<body>
<form method="post" action="mail.asp">
<p>Nombre:
<input type="text" name="nom">
</p>
<p>Empresa:
<input type="text" name="emp">
</p>
<p>Sugerencias:
<textarea name="sug" cols="35"></textarea>
</p>
<p>
<input type="submit" name="Submit" value="Enviar">
<input type="reset" name="Submit2" value="Limpiar">
</p>
</form>
</body>
</html>

Por otro lado tendremos una página a la que llamaremos mail.asp.
El código es el siguiente:

<%
'Creación de variables para almacenar los campos del formulario

Nombre= Request.Form("nom")
Empresa= Request.Form("emp")
Sugerencias= Request.Form("sug")

strTo = "direccion@tudominio.com" ' Esta es una dirección que corresponda a
nuestro servidor
strSubject = "Envio de sugerencias de: " & Nombre

strBody = "<html><body>"
strBody = strBody & "Este es un mensaje generado por el formulario:" &
"<br><br>"
strBody = strBody & "Nombre: "& Nombre &"<br>"
strBody = strBody & "Empresa: "& Empresa &"<br>"
strBody = strBody & "Sugerencias: "& Sugerencias &"<br>"
strBody = strBody & "</body></html>"

Set objCDOMail = Server.CreateObject("CDONTS.NewMail") 'Creación del objeto

objCDOMail.From = "direccion@tudominio.com" 'No hay problema en que sea la
misma que la anterior.
objCDOMail.To = strTo
objCDOMail.Subject = strSubject

objCDOMail.BodyFormat=0 'Estas dos línes
objCDOMail.MailFormat=0 'permiten formatear mejor el mensaje

objCDOMail.Body = strBody
objCDOMail.Send 'Envía el mail
Set objCDOMail = Nothing
Response.redirect "gracias.html"
' O bien podemos ahorrar una página y escribir algo como
' Response.write "Gracias por enviarnos sus sugerencias"
%>

Por último debemos generar una página con un mensaje de agradecimiento, o bien redireccionar al visitante hacia otra página de nuestro sitio.

Cómo mostrar la cantidad de usuarios activos en nuestro sitio

Algo que puede llegar a ser muy interesante, es saber cuanto usuarios hay visitando nuestro sitio al mismo tiempo, ya sea como un servicio más del sitio o bien para realizar algunas estadísticas, que nos permitan conocer mejor las visitas de los usuarios.
Para realizar este ejemplo, vamos a utilizar el archivo Global.asa y cuatro eventos, para manejar las rutinas.

Application_OnStart
Application_OnEnd
Session_OnStart
Session_OnEnd

El archivo Global.asa debe quedar asi:

<SCRIPT LANGUAGE=VBScript RUNAT=Server>
Sub Application_OnStart
Application("visitas") = 0
Application("Active") = 0
End Sub
Sub Application_OnEnd
End Sub

Sub Session_OnStart
Session.Timeout = 20
Session("Start") = Now
Application.lock
Application("visitas") = Application("visitas") + 1
intTotal_visitas = Application("visitas")
Application.unlock
Session("VisitorID") = intTotal_visitas

Application.lock
Application("Active") = Application("Active") + 1
Application.unlock
End Sub

Sub Session_OnEnd
Application.lock
Application("Active") = Application("Active") - 1
Application.unlock
End Sub
</SCRIPT>

Ahora sólo nos falta crear el archivo mostrarvisitas.asp y listo.

<html>
<head>
<title>Mostrando la cantidad de usuarios activos</title>
</head>
<body>
Vos sos uno, de <%=Application("Active")%> visitantes en este momento.
</body>
</html>

Implementando un sistema de Banners Rotativos

Uno de los componentes más útiles que se pueden emplear en ASP es el llamado Ad Rotator, este componente permite mostrar distintos banners en una página ASP, pudiendo calcular mediante porcentajes, la cantidad de veces que queremos mostrar los banners e incluso controlar las veces en que el usuario hace click en alguno de los banners.
El componente ad Rotator es incluído con el Windows NT Option Pack, cuando instales el Internet Informatión Server, el componente debería instalarse automáticamente en la carpeta, C:\Winnt\system32\inetsrv\ADROT.dll.

Vamos a crear para el ejemplo los archivos necesarios banners.asp, banners.txt adredir.asp.

banners.asp
<HTML>
<HEAD><TITLE> Mostrando Banners</TITLE></HEAD>

<BODY>
<CENTER><H1>Mostrando Distintos Banners!</H1></CENTER>

<HR>
<%
Set MyAd=Server.CreateObject("MSWC.AdRotator")
MyAd.TargetFrame= "TARGET=""blank"""
%>

<CENTER><%= MyAd.GetAdvertisement("banners.txt") %></CENTER>
</BODY>
</HTML>

En esta página es en donde vamos a mostrar los distintos banners, y para ello necesitamos crear 2 archivos más.

banners.txt
REDIRECT adredir.asp
WIDTH 468
HEIGHT 60
BORDER 0
*
banner1.gif
http://www.lavariable.com
El Portal de Programación en Internet
60
banner2.gif
http://www.webklan.com.ar
WebKlan
20
banner3.gif
http://www.neolatina.com
Neolatina
20

Tenemos algunas propiedades para explicar.

Redirect: Especifica la dirección en donde el usuario que clickea en el banner es enviado.

Width: Especifíca el largo que tendran el o los banners que mostremos, el tamaño estandar que se utiliza habitualmente es de 468 pixels.

Height: Especifíca el alto que tendran el o los banners que mostremos, el tamaño estandar que se utiliza habitualmente es de 60 pixels.

Border: Este es el valor que le damos al borde del banner, lo habitual es no usar borde, por lo tanto tenemos que colocar un 0 en esta propiedad.

adredir.asp

<%
Response.AppendToLog Request.QueryString("url")
Response.Redirect Request.QueryString("url")
%>